{$CLEO}
thread 'IN4'
const
    CURRENT_HOUR = 2@
    fX_POS = 315.364
    fY_POS = -1811.82
    fZ_POS = 6.76562
    fRad = 80.5
end // const
 
while true
    wait 250
    if 
        0256:   player $PLAYER_CHAR defined         
    then        
        00BF: CURRENT_HOUR = current_time_hours, 3@ = current_time_minutes          
        if and
            0029:   CURRENT_HOUR >= 6 
            001B:   20 > CURRENT_HOUR
            00FE:   actor $PLAYER_ACTOR sphere 0 in_sphere fX_POS fY_POS fZ_POS radius fRad fRad fRad
        then 
            #WFYPRO.Load            
            while not #WFYPRO.Available
                wait 0
            end
            009A: 0@ = create_actor_pedtype 24 model #WFYPRO at fX_POS fY_POS fZ_POS
            0249: release_model #WFYPRO
 
            04ED: load_animation "PARK"              
            while 84EE:   NOT animation "PARK" loaded
                wait 0        
            end
            0812: AS_actor 0@ perform_animation "TAI_CHI_IN" IFP "PARK" framedelta 4.0 loopA 1 lockX 0 lockY 0 lockF 0 time -1 // versionB                          
            while true
                wait 250 
                00BF: CURRENT_HOUR = current_time_hours, 3@ = current_time_minutes                 
                if and
                    0256:   player $PLAYER_CHAR defined 
                    0029:   CURRENT_HOUR >= 6 
                    001B:   20 > CURRENT_HOUR 
                then 
                    if or
                        0118:   actor 0@ dead
                        80FE:   not actor $PLAYER_ACTOR sphere 0 in_sphere fX_POS fY_POS fZ_POS radius fRad fRad fRad 
                    then
                        break
                    end                                                                           
                    if 
                        051A:   actor 0@ damaged_by_actor $PLAYER_ACTOR 
                    then
                        0792: disembark_instantly_actor 0@ 
                        0223: set_actor 0@ health_to 0
                        break  
                    end
                else
                    break
                end
            end
            04EF: release_animation "PARK" 
            009B: destroy_actor 0@            
            while 0256:   player $PLAYER_CHAR defined 
                wait 250 ms 
                if 
                    80FE:   not actor $PLAYER_ACTOR sphere 0 in_sphere 315.364 -1811.82 6.76562 radius 80.5 80.5 80.5 
                then
                    break 
                end
            end 
        end
    end
end