Всех кто знает скриптинг, прошу помочь.

Ty6ePkYJIe3 · 17-02-2011 18:31

Кто знает, объясните, пожалуйста, где ошибка и почему я вылетаю?Очень прошу помогите. cry
{$CLEO .cs}
0000: NOP
:NONAME_2
wait 0
if
Player.Defined($PLAYER_ACTOR)
Actor.Driving($PLAYER_ACTOR)
jf @NONAME_2
:load
wait 0
03C0: $CAR = actor $PLAYER_ACTOR car
:NONAME_39
wait 0
if
801C: not car $CAR health >= 950
jf @NONAME_39
:NONAME_75
wait 0
Car.SetImmunities($CAR, 1, 1, 1, 1, 1)
066B: $ATCH = attach_particle "EXPLOSION_LARGE" to_car $CAR with_offset 0.0 0.0 0.0 flag 1
wait 0
064C: make_particle $ATCH visible
wait 20
0650: destroy_particle $ATCH
wait 0
0407: store_coords_to 2@ 3@ 4@ from_car $CAR with_offset 0.0 0.0 0.0
020C: create_explosion_with_radius 10 at 2@ 3@ 4@
0948: create_explosion_at 2@ 3@ 4@ type 10 camera_shake 1
0565: create_soundless_explosion_at 2@ 3@ 4@ type 10
wait 3000
Car.SetImmunities($CAR, 0, 0, 0, 0, 0)
Car.Health($CAR) = 1000
jump @NONAME_2

~AquaZ~ · 17-02-2011 20:12

1. Чтоб что-то было понятно существует тег [cоde][/codе]
2.

if 
Player.Defined($PLAYER_ACTOR)
Actor.Driving($PLAYER_ACTOR)
jf @NONAME_2

Когда много проверок, ставится if and или if or

if and
  Player.Defined($PLAYER_ACTOR)
  Actor.Driving($PLAYER_ACTOR)
jf @NONAME_2

3. Предыдущий фрагмент в принципе не правильный, т.к. проверка Player.Defined должна отделяться от всего.
4. В КЛЕО НЕЛЬЗЯ использовать глобальные переменные!!!!!!!!!!1111111
Вот поправленный не тестированный код.

{$CLEO .cs}
0000:

:START
wait 10
if 
  Player.Defined($PLAYER_ACTOR)
jf @START
if
  Actor.Driving($PLAYER_ACTOR)
jf @START
03C0: 0@ = actor $PLAYER_ACTOR car 
if 
  801C: not car 0@ health >= 950  
jf @START
Car.SetImmunities(0@, 1, 1, 1, 1, 1)
066B: 1@ = attach_particle "EXPLOSION_LARGE" to_car 0@ with_offset 0.0 0.0 0.0 flag 1 
wait 0
064C: make_particle 1@ visible 
wait 20000
0650: destroy_particle 1@
0407: store_coords_to 2@ 3@ 4@ from_car 0@ with_offset 0 0 0
020C: create_explosion_with_radius 10 at 2@ 3@ 4@
0948: create_explosion_at 2@ 3@ 4@ type 10 camera_shake 1 
0565: create_soundless_explosion_at 2@ 3@ 4@ type 10 
wait 3000 
Car.SetImmunities($CAR, 0, 0, 0, 0, 0)
Car.Health($CAR) = 1000
jump @START

По коду приблизительно закрадывается идея, что скрипт делает взрыв возле тачки если её ушибить...

Ty6ePkYJIe3 · 17-02-2011 20:50

спасибо за то, что исправил указал ошибки, буду знать, но всё равно вылетает cry , я почему то ссылаюсь на данную строчку
801C: not car 0@ health >= 950 можел ли тут, быть какая-то ошибка?

Den_spb · 17-02-2011 22:25

Car.SetImmunities($CAR, 0, 0, 0, 0, 0)
Car.Health($CAR) = 1000

Это необходимо заменить на

Car.SetImmunities(0@, 0, 0, 0, 0, 0)
Car.Health(0@) = 1000

Иначе игра вылетит, т.к. будет произведена попытка выполнения действий над несуществующей машиной $CAR.
Ну и если есть желание научиться писать качественные скрипты, то надо привыкать применять проверки на существование - они позволят избежать вылета, если машину (актёра, объект) удалила игра или другой скрипт. Результат проверки действителен с момента её проведения до первой после неё команды wait.

{$CLEO .cs}
0000:

:START
wait 10
if 
  Player.Defined($PLAYER_ACTOR)
jf @START
if
  Actor.Driving($PLAYER_ACTOR)
jf @START
03C0: 0@ = actor $PLAYER_ACTOR car 
if 
  801C: not car 0@ health >= 950  
jf @START
Car.SetImmunities(0@, 1, 1, 1, 1, 1)
066B: 1@ = attach_particle "EXPLOSION_LARGE" to_car 0@ with_offset 0.0 0.0 0.0 flag 1 
064C: make_particle 1@ visible 
wait 20000
0650: destroy_particle 1@
if
  056E:   car 0@ defined 
jf @START
0407: store_coords_to 2@ 3@ 4@ from_car 0@ with_offset 0 0 0
020C: create_explosion_with_radius 10 at 2@ 3@ 4@
0948: create_explosion_at 2@ 3@ 4@ type 10 camera_shake 1 
0565: create_soundless_explosion_at 2@ 3@ 4@ type 10 
wait 3000
if
  056E:   car 0@ defined 
jf @START 
Car.SetImmunities(0@, 0, 0, 0, 0, 0)
Car.Health(0@) = 1000
jump @START

Last edited by Den_spb (17-02-2011 22:26)

Ty6ePkYJIe3 · 18-02-2011 06:34

хм,все равно не работает(
но если поменять это условие:

if
801C: not car 0@ health >= 950
jf @START
на условие нажатия клавиши,то он работает, можно ли заменить это условие:
801C: not car 0@ health >= 950
на другое, но что бы смысл был тот же?

Last edited by Ty6ePkYJIe3 (18-02-2011 06:35)

Sw[ee]t · 18-02-2011 12:18

Нет, нельзя.
Используй заместо 03C0: 0@ = actor $PLAYER_ACTOR car
Это:

...
0AB5: $PLAYER_ACTOR 0@ $_UNUSED
if
  actor.incar($PLAYER_ACTOR,0@)
jf @START
...

Мною было замечено, что 03C0 отказывается работать в клео4 вообще ибо всегда возвращает -1. Даже на миссиях.

Ty6ePkYJIe3 · 18-02-2011 13:04

Нет, даже так ничего не получается(
Но я 100% знаю, что обрываеться всё на опкоде
801C: not car 0@ health >= 950, а вот как исправить незнаю...

Den_spb · 18-02-2011 15:37

Но я 100% знаю, что обрываеться всё на опкоде
801C: not car 0@ health >= 950, а вот как исправить незнаю...

Ты прав, причина вылета в этом опкоде. Дело в том, что назначение у этого опкода абсолютно другое - сравнение значений двух переменных:

801C: not  $CURRENT_MONTH_DAY > $GYM_MONTH_DAY_WHEN_LIMIT_REACHED // (int)

А опкод для сравнения здоровья машины с числом несложно найти через поиск опкодов (Сервис - Инструменты - Поиск опкодов):

8185: not car 73@ health >= 700

Мною было замечено, что 03C0 отказывается работать в клео4 вообще ибо всегда возвращает -1. Даже на миссиях.

Лично у меня данный 03C0 на клео4 работает без проблем.

Ty6ePkYJIe3 · 18-02-2011 16:17

Всё работает! Огромное всем спасибо за то, что дали понять, что неправельно и огромное спасибо тебе Den_spb за этот каверзный опкод)):^

~AquaZ~ · 18-02-2011 19:21

Туберкулёз, в где ты взял опкод в таком виде?

Ty6ePkYJIe3 · 19-02-2011 07:21

Из учебника для "чайников" откуда же еще grin

~AquaZ~ · 19-02-2011 11:11

Покажи, пожалуйста smile

Ty6ePkYJIe3 · 19-02-2011 13:07

Вот он в оригенальном виде, а у меня был просто переделанный grin
801C: not $Var_1 >= $Var_1

Last edited by Ty6ePkYJIe3 (19-02-2011 13:10)

Den_spb · 19-02-2011 13:21

Так опкоды переделывать нельзя, потому что смысл опкода зависит только от его номера. А описательная часть ни на что не влияет - её можно вообще не писать.

Ty6ePkYJIe3 · 19-02-2011 17:36

Хм, ну я в скриптинге особо не разбираюсь, "чайник" же ещё grin

Ty6ePkYJIe3 · 19-02-2011 17:43

И ещё вопрос, кто знает, что это такое? Точнее как это читаеться и работает?
&0(15@,1i) == 16711680

Last edited by Ty6ePkYJIe3 (19-02-2011 17:44)

~AquaZ~ · 19-02-2011 19:25

Работа с памятью через ячейку массива. RTFM

Ty6ePkYJIe3 · 19-02-2011 19:53

Уууу, кароче мне до этого ещё далеко grin

Ty6ePkYJIe3 · 20-02-2011 11:15

И ещё вопрос, как работает команда: gosub, а то сколько я не пробовал понять, немогу sad

Sw[ee]t · 20-02-2011 14:13

Госуб - безусловный переход...
а вообще, почитай вот это - клик

Ty6ePkYJIe3 · 20-02-2011 14:44

Вот теперь понимаю, спасибо тебе smile

Ty6ePkYJIe3 · 21-02-2011 15:45

Люди, как сделать так, чтобы данные о машине удалялись если игрок её невидит,

но скрипт до этого момента продолжал работать с начала?

SannyBuilder.com Forums

#1 17-02-2011 18:31

Всех кто знает скриптинг, прошу помочь.

#2 17-02-2011 20:12

Re: Всех кто знает скриптинг, прошу помочь.

#3 17-02-2011 20:50

Re: Всех кто знает скриптинг, прошу помочь.

#4 17-02-2011 22:25

Re: Всех кто знает скриптинг, прошу помочь.

#5 18-02-2011 06:34

Re: Всех кто знает скриптинг, прошу помочь.

#6 18-02-2011 12:18

Re: Всех кто знает скриптинг, прошу помочь.

#7 18-02-2011 13:04

Re: Всех кто знает скриптинг, прошу помочь.

#8 18-02-2011 15:37

Re: Всех кто знает скриптинг, прошу помочь.

#9 18-02-2011 16:17

Re: Всех кто знает скриптинг, прошу помочь.

#10 18-02-2011 19:21

Re: Всех кто знает скриптинг, прошу помочь.

#11 19-02-2011 07:21

Re: Всех кто знает скриптинг, прошу помочь.

#12 19-02-2011 11:11

Re: Всех кто знает скриптинг, прошу помочь.

#13 19-02-2011 13:07

Re: Всех кто знает скриптинг, прошу помочь.

#14 19-02-2011 13:21

Re: Всех кто знает скриптинг, прошу помочь.

#15 19-02-2011 17:36

Re: Всех кто знает скриптинг, прошу помочь.

#16 19-02-2011 17:43

Re: Всех кто знает скриптинг, прошу помочь.

#17 19-02-2011 19:25

Re: Всех кто знает скриптинг, прошу помочь.

#18 19-02-2011 19:53

Re: Всех кто знает скриптинг, прошу помочь.

#19 20-02-2011 11:15

Re: Всех кто знает скриптинг, прошу помочь.

#20 20-02-2011 14:13

Re: Всех кто знает скриптинг, прошу помочь.

#21 20-02-2011 14:44

Re: Всех кто знает скриптинг, прошу помочь.

#22 21-02-2011 15:45

Re: Всех кто знает скриптинг, прошу помочь.

Board footer