Левитация

аХыЕгоЗы · 05-08-2008 12:50

Управление очень простое:
F4 - вкл/выкл;
W, стрелка вверх, или что там заставляет у вас CJ-я двигаться вперед - лететь.

{$CLEO}

04ed: load_animation "PARACHUTE"
:anim
wait 0
04EE: animation "PARACHUTE" loaded
jf @anim

:check
wait 0
if and
0AB0:  key_pressed 0x73
not actor.Driving($PLAYER_ACTOR)
jf @check

:check_2                     
wait 0                                       
8AB0: not key_pressed 0x73   
jf @check_2                  

actor.LockInCurrentPosition($PLAYER_ACTOR,true) 
actor.StorePos($PLAYER_ACTOR, 1@, 2@, 3@)        
3@ += 0.5
actor.PutAt($PLAYER_ACTOR,1@,2@,3@)

:levi
wait 0
068D: get_camera_position_to 4@ 5@ 6@
actor.StorePos($PLAYER_ACTOR, 1@, 2@, 3@)        
000f: 1@ -= 4@
000f: 2@ -= 5@
000f: 3@ -= 6@
1@ *= 15.0
2@ *= 15.0
3@ *= 15.0
3@ += 4.5
0604: get_Z_angle_for_point 1@ 2@ store_to 7@
actor.Angle($PLAYER_ACTOR) = 7@
0812: AS_actor $PLAYER_ACTOR perform_animation "FALL_SKYDIVE" IFP_file "PARACHUTE" 1.0 loopA 0 lockX 0 lockY 0 lockF 1 time 15
0494: get_joystick 0 data 28@ 29@ 30@ 31@
0 > 29@
jf @checkquit

02AB: set_actor $PLAYER_ACTOR immunities BP 0 FP 0 EP 0 CP 1 MP 0 
actor.LockInCurrentPosition($PLAYER_ACTOR,false)
083C: set_actor $PLAYER_ACTOR velocity_in_direction_XYZ 1@ 2@ 3@ 
066A: 8@ = attach_particle "gunflash" to_actor $PLAYER_ACTOR with_offset 0.0 -0.3 -0.05 rotation 0.0 -1.0 0.0 flag 1 
064C: make_particle 8@ visible 
jump @levi

:checkquit
wait 0
0650: destroy_particle 9@ 
actor.LockInCurrentPosition($PLAYER_ACTOR,true)
02AB: set_actor $PLAYER_ACTOR immunities BP 0 FP 0 EP 0 CP 0 MP 0 
0AB0:  key_pressed 0x73
jf @levi

:quit
wait 0
8AB0: not key_pressed 0x73
jf @quit

actor.LockInCurrentPosition($PLAYER_ACTOR, false)
actor.StorePos($PLAYER_ACTOR, 1@, 2@, 3@)        
3@ += 0.01
actor.PutAt($PLAYER_ACTOR,1@,2@,3@)
jump @check

PriMan · 05-08-2008 17:37

Отличный скрипт! Летал прямтаки как Hancock, осталось только добавить возможность разносить столбы и машины при соприкосновении и клубы пыли при посадке на асфальт...

Noob · 06-08-2008 10:23

Вот это да!!! ПРикольнуло нитро из задницы XD. Подскажите как его убрать.

Хочу чуть изменить видок, чтоб летал он как Нео из матрицы, но я уже сам попробую, вот только не нашел я в помощи SB других анимаций парашюта, напишите или скажите, где я их могу найти.

Блин еще вопрос: Как сделать, чтобы когда нажмем левую кнопку мыши - он ускоряется, а когда правую - замедляется? Я пытался, но не вышло.

СПАСИБО!

Last edited by Noob (06-08-2008 13:37)

PriMan · 06-08-2008 14:49

Чтобы убрать огонь удали строку:

066A: 8@ = attach_particle "gunflash" to_actor $PLAYER_ACTOR with_offset 0.0 -0.3 -0.05 rotation 0.0 -1.0 0.0 flag 1

Agenzvell · 07-08-2008 03:58

PriMan wrote:

Чтобы убрать огонь удали строку:
066A: 8@ = attach_particle "gunflash" to_actor $PLAYER_ACTOR with_offset 0.0 -0.3 -0.05 rotation 0.0 -1.0 0.0 flag 1

Лучше стереть это:

066A: 8@ = attach_particle "gunflash" to_actor $PLAYER_ACTOR with_offset 0.0 -0.3 -0.05 rotation 0.0 -1.0 0.0 flag 1 
064C: make_particle 8@ visible

Noob · 07-08-2008 06:17

Спасибо, а что насчет этого?

Хочу чуть изменить видок, чтоб летал он как Нео из матрицы, но я уже сам попробую, вот только не нашел я в помощи SB других анимаций парашюта, напишите или скажите, где я их могу найти.
Блин еще вопрос: Как сделать, чтобы когда нажмем левую кнопку мыши - он ускоряется, а когда правую - замедляется? Я пытался, но не вышло.

И еще: вот когда он до земли дотрагивается - он не хочет лететь. Как это исправить?

Agenzvell · 07-08-2008 06:56

{$CLEO}

:load
wait 0
04ED: load_animation "PARACHUTE"
038B: load_requested_models 

:anim
wait 0
if
04EE: animation "PARACHUTE" loaded
jf @anim

:check
wait 0
if and
0AB0:  key_pressed 0x74
not actor.Driving($PLAYER_ACTOR)
jf @check

:check_2                     
wait 0             
 if                         
8AB0: not key_pressed 0x73   
jf @check_2                  
actor.LockInCurrentPosition($PLAYER_ACTOR,true) 
actor.StorePos($PLAYER_ACTOR, 1@, 2@, 3@)        
3@ += 10.5
actor.PutAt($PLAYER_ACTOR,1@,2@,3@)

:levi
wait 0
068D: get_camera_position_to 4@ 5@ 6@
actor.StorePos($PLAYER_ACTOR, 1@, 2@, 3@)        
000f: 1@ -= 4@
000f: 2@ -= 5@
000f: 3@ -= 6@
1@ *= 15.0
2@ *= 15.0
3@ *= 15.0
3@ += 4.5
0604: get_Z_angle_for_point 1@ 2@ store_to 7@
actor.Angle($PLAYER_ACTOR) = 7@
0812: AS_actor $PLAYER_ACTOR perform_animation "FALL_SKYDIVE_ACCEL" IFP_file "PARACHUTE" 1.0 loopA 0 lockX 0 lockY 0 lockF 1 time 15
0494: get_joystick 0 data 28@ 29@ 30@ 31@
if
0 > 29@
jf @checkquit
02AB: set_actor $PLAYER_ACTOR immunities BP 0 FP 0 EP 0 CP 1 MP 0 
actor.LockInCurrentPosition($PLAYER_ACTOR,false)
083C: set_actor $PLAYER_ACTOR velocity_in_direction_XYZ 1@ 2@ 3@ 
jump @levi

:checkquit
wait 0
actor.LockInCurrentPosition($PLAYER_ACTOR,true)
02AB: set_actor $PLAYER_ACTOR immunities BP 0 FP 0 EP 0 CP 0 MP 0 
if
0AB0:  key_pressed 0x74
jf @levi

:quit
wait 0
if
8AB0: not key_pressed 0x74
jf @quit
actor.LockInCurrentPosition($PLAYER_ACTOR, false)
actor.StorePos($PLAYER_ACTOR, 1@, 2@, 3@)        
3@ += 0.01
actor.PutAt($PLAYER_ACTOR,1@,2@,3@)
jump @check

Исправил ошибки. Убрал огонь из одного места, добавил нужные проверки, загрузил как надо анимацию итп.

Last edited by Agenzvell (07-08-2008 06:59)

аХыЕгоЗы · 08-08-2008 18:27

Agenzvell wrote:

Исправил ошибки. ... добавил нужные проверки, загрузил как надо анимацию итп.

Очень пафосно звучит.
Кстати, зачем ты добавил после загрузки файла анимации

038B: load_requested_model

? Анимация - это же не модель. Или я не прав?

И разве отсутствие if перед одиночными проверками - это ошибка? Они же необязательны? Или я опять неправ?

Потом у тебя конструкция

:check
wait 0
if and
0AB0:  key_pressed 0x74
not actor.Driving($PLAYER_ACTOR)
jf @check

:check_2                     
wait 0             
 if                         
8AB0: not key_pressed 0x73   
jf @check_2

Т.е. ты проверяешь, нажата ли клавиша F5, а потом - отпущена ли F4?
Это само есть ошибка, так как пока F5 нажата, скрипт может успеть выполниться и начнется вот эта проверка

:checkquit
wait 0
actor.LockInCurrentPosition($PLAYER_ACTOR,true)
02AB: set_actor $PLAYER_ACTOR immunities BP 0 FP 0 EP 0 CP 0 MP 0 
if
0AB0:  key_pressed 0x74
jf @levi

:quit
wait 0
if
8AB0: not key_pressed 0x74
jf @quit

Т.е проверка на выход.

Agenzvell · 10-08-2008 04:20

Гы, про F4 и вправду не заметил smile Просто на F4 забинден скрипт сохранения. If надо ставить перед каждой проверкой. Про анимацию - загружаю её всегда так, вылетов не замечал при такой загрузке, поэтому и использую.

flashTrash · 10-08-2008 05:38

@Agenzvell
IF НЕ надо ставить перед одиночными проверками(кроме опкодов "if and set")
А 038B и в правду лишний smile

Capushon · 11-08-2008 20:56

@Agenzvell -
Ошибки. Отсутствуют проверки -

1. нигде нет проверок "жив ли игрок".
2 если игрок уже выполняет другую анимацию (например падает, или плывёт), а мод по нажатию клавиши прицепит на него анимацию парашута, как думаешь что может быть с игрой?
3. если у актёра будет 1-10% жизни и в момент прицепки анимации его подстрелят, что будет?
4. если в момент полёта игрок попадёт зону действия маркера миссии, что будет?
5. если миссия уже идёт а игрок решит полетать?
6. если игрок в интерьере полетает? Он вылетит за его педелы ...
7. а под водой ...
8. ...

Мод будет работать стабильно только в идеальных для него условиях.

Agenzvell · 12-08-2008 04:40

@Capushon
Нет, полностью переписывать скрипт я не собираюсь smile

@flashTrash
3амечания учел, спасибо за поправки.

R3B007 · 16-08-2008 17:04

Кнопку где там изменить? F4 не потходить какбэ

-Dimon- · 21-08-2008 17:05

Вот отредактировал.
Добавил проверки и изменил в место F4 теперь Shift + Space + LKM (Спринт + Прыжок + Стрелять)

{$CLEO .cs}

0000: NOP

:load
wait 100
if
  Player.Defined($PLAYER_CHAR)
jf @load
if
  not Actor.Driving($PLAYER_ACTOR)
jf @load
077E: get_active_interior_to $ACTIVE_INTERIOR 
if and
  $ONMISSION == 0
  0038:   $ACTIVE_INTERIOR == 0 
jf @load
if and
   0AB0:  key_pressed 16
   0AB0:  key_pressed 32
   00E1:  key_pressed 0 17
jf @load
04ED: load_animation "PARACHUTE"

:anim
wait 100
if
  04EE: animation "PARACHUTE" loaded
jf @anim

:check_2                     
wait 0                               
actor.LockInCurrentPosition($PLAYER_ACTOR,true) 
actor.StorePos($PLAYER_ACTOR, 1@, 2@, 3@)        
3@ += 10.5
actor.PutAt($PLAYER_ACTOR,1@,2@,3@)

:levi
wait 0
068D: get_camera_position_to 4@ 5@ 6@
actor.StorePos($PLAYER_ACTOR, 1@, 2@, 3@)        
000f: 1@ -= 4@
000f: 2@ -= 5@
000f: 3@ -= 6@
1@ *= 15.0
2@ *= 15.0
3@ *= 15.0
3@ += 4.5
0604: get_Z_angle_for_point 1@ 2@ store_to 7@
actor.Angle($PLAYER_ACTOR) = 7@
0812: AS_actor $PLAYER_ACTOR perform_animation "FALL_SKYDIVE_ACCEL" IFP_file "PARACHUTE" 1.0 loopA 0 lockX 0 lockY 0 lockF 1 time 15
0494: get_joystick 0 data 28@ 29@ 30@ 31@
if
0 > 29@
jf @checkquit
02AB: set_actor $PLAYER_ACTOR immunities BP 1 FP 1 EP 1 CP 1 MP 1 
actor.LockInCurrentPosition($PLAYER_ACTOR,false)
083C: set_actor $PLAYER_ACTOR velocity_in_direction_XYZ 1@ 2@ 3@ 
jump @levi

:checkquit
wait 0
actor.LockInCurrentPosition($PLAYER_ACTOR,true)
02AB: set_actor $PLAYER_ACTOR immunities BP 0 FP 0 EP 0 CP 0 MP 0 
if and
   0AB0:  key_pressed 16
   0AB0:  key_pressed 32
   00E1:  key_pressed 0 17
jf @levi

:quit
wait 0
if and
   8AB0: not key_pressed 16
   8AB0: not key_pressed 32
   80E1: not key_pressed 0 17
jf @quit
actor.LockInCurrentPosition($PLAYER_ACTOR, false)
actor.StorePos($PLAYER_ACTOR, 1@, 2@, 3@)        
3@ += 0.01
actor.PutAt($PLAYER_ACTOR,1@,2@,3@)
04EF: release_animation "PARACHUTE" 
jump @load

Noob · 23-08-2008 07:35

-Dimon-, сделай чтобы когда жмем левую кнопку мыши, скорость полета постепенно увеличивалась, а когда жмем правую - уменьшалась. Резкий тормоз на правый Ctrl.

Last edited by Noob (23-08-2008 07:35)

Capushon · 23-08-2008 11:58

@-Dimon- -
Если в цикле levi игрока подстрелят - скрипт зависнет, т.к. считывание координат и установка будет отноститься уже не к нему, а к мёртвому телу...

-Dimon- · 26-08-2008 05:41

@Capushon - Не зависнет, игрок появится около больницы в активированной левитации... И также если налетит на маркер... И ещё, смотри, у игрока стоят иммунитеты на всё)

SerJo · 04-09-2008 20:32

пара вопросов:
1. какой параметр отвечает за скорость полета?
2. можно ли сделать такой скрипт, который будет перемещать игрока во время левитации вверх/вниз при нажатии соответствующих клавиш?

Serega373 · 21-09-2008 20:00

Скорость полёта регулируется ! Чем дальше камера тем быстрей летит А если надеть парашут и отдалить камеру как можно дальше то летит быстрей многих самолётов:cool:

Вовчик_гадкий · 28-11-2008 22:31

А можно вопрос Это как так?

066A: 8@ = attach_particle "gunflash" to_actor $PLAYER_ACTOR with_offset 0.0 -0.3 -0.05 rotation 0.0 -1.0 0.0 flag 1
064C: make_particle 8@ visible //Загвоздка он будет дублироваться. а значит эффект будет засирать усё подряд. Перед проверкой нажатия нужно "ставить Уборку аффекта".
jump @levi

:checkquit
wait 0
0650: destroy_particle 9@ ???? И хде его, ипать что ли?

SambukaYoup · 26-11-2011 11:17

Господа,а зачем этот скрипт есть же в собейте как раз такой на ю жмешь и летаешь ).:wow:

Den_spb · 26-11-2011 23:03

Не все используют собейт.

SannyBuilder.com Forums

#1 05-08-2008 12:50

Левитация

#2 05-08-2008 17:37

Re: Левитация

#3 06-08-2008 10:23

Re: Левитация

#4 06-08-2008 14:49

Re: Левитация

#5 07-08-2008 03:58

Re: Левитация

#6 07-08-2008 06:17

Re: Левитация

#7 07-08-2008 06:56

Re: Левитация

#8 08-08-2008 18:27

Re: Левитация

#9 10-08-2008 04:20

Re: Левитация

#10 10-08-2008 05:38

Re: Левитация

#11 11-08-2008 20:56

Re: Левитация

#12 12-08-2008 04:40

Re: Левитация

#13 16-08-2008 17:04

Re: Левитация

#14 21-08-2008 17:05

Re: Левитация

#15 23-08-2008 07:35

Re: Левитация

#16 23-08-2008 11:58

Re: Левитация

#17 26-08-2008 05:41

Re: Левитация

#18 04-09-2008 20:32

Re: Левитация

#19 21-09-2008 20:00

Re: Левитация

#20 28-11-2008 22:31

Re: Левитация

#21 26-11-2011 11:17

Re: Левитация

#22 26-11-2011 23:03

Re: Левитация

Board footer