#26 21-02-2009 08:44

Seemann
Registered: 07-08-2006
Posts: 2,155

Re: Нажатие клавиш

Сделай вот так:

{$CLEO}
0000:
while true
    wait 250 ms
    0@s = 'weapon'
    if
        0256:   player $PLAYER_CHAR defined
    then 
        if
            0AB1: call_scm_func @TestCheat 2 0@ 1@
        then
            gosub @ShowPanel     
        end
    end
end    

:ShowPanel
Player.CanMove($PLAYER_CHAR) = False
08D4: 1@ = create_panel_with_title 'FES_WEA' position 31.0 110.0 width 80.0 columns 2 interactive 1 background 1 alignment 0  // ’“ K 
08DB: set_panel 1@ column 0 header 'DUMMY' data 'M4' 'AK' 'SHOTGN1' 'SHOTGN3' 'SHOTGN2' 'STWE003' 'STWE002' 'STWE001' 'GUN3' 'MP5' 'STWE011' 'RIFLE'  // M4 // ak47 // €PO…OB K // PA‡PƒBHO  B HT4ECTEP // …OEBO  €PO…OB K // ’“CTƒHHƒ  OPE‚ // T X   ’ CTO‚ET // ’ CTO‚ET // M KPO ’O‚“-ABTOMATƒ // CM† // TEK9 // B HTOBKA
08D6: set_panel 1@ column 0 alignment 1 
08D6: set_panel 1@ column 1 alignment 2 
09DB: set_panel 1@ column 0 width 140 
09DB: set_panel 1@ column 1 width 46 
090E: set_panel 1@ active_row 0 

while true
    wait 250
    if
        0256:   player $PLAYER_CHAR defined
    then 
        // remove menu
        if 
            0AB0:   key_pressed 13 // Enter
        then 
            jump @MenuExit
        end

        // give weapon
        if 
            0AB0:   key_pressed 16  // Shift
        then 
            08D7: 2@ = panel 1@ active_row
            gosub @WeaponTable
            jump @MenuExit 
        end
    else
        return
    end
end

:MenuExit
03E6: remove_text_box 
Player.CanMove($PLAYER_CHAR) = True
08DA: remove_panel 1@
return   

:WeaponTable
0871: init_jump_table 2@ total_jumps 13 default_jump 0 @NoWeapon jumps 0 @M4 1 @AK47 2 @CHROMEGUN 3 @SHOTGSPA 4 @SAWNOFF 5 @DESERT_EAGLE 6 @SILENCED 
0872: jump_table_jumps 7 @COLT45 8 @MICRO_UZI 9 @MP5LNG 10 @TEC9 11 @CUNTGUN 12 @SNIPER -1 @NoWeapon -1 @NoWeapon -1 @NoWeapon 

:M4
0AB1: call_scm_func @GiveWeapon 3 #M4 31 3800
return

:AK47 
0AB1: call_scm_func @GiveWeapon 3 #AK47 30 3800
return

:CHROMEGUN
0AB1: call_scm_func @GiveWeapon 3 #CHROMEGUN 25 4000
return

:SHOTGSPA
0AB1: call_scm_func @GiveWeapon 3 #SHOTGSPA 27 4000
return

:SAWNOFF
0AB1: call_scm_func @GiveWeapon 3 #SAWNOFF 26 4000
return

:DESERT_EAGLE
0AB1: call_scm_func @GiveWeapon 3 #DESERT_EAGLE 24 4000
return

:SILENCED
0AB1: call_scm_func @GiveWeapon 3 #SILENCED 23 4000
return

:COLT45
0AB1: call_scm_func @GiveWeapon 3 #COLT45 22 4000
return

:MICRO_UZI
0AB1: call_scm_func @GiveWeapon 3 #MICRO_UZI 28 7000
return

:MP5LNG
0AB1: call_scm_func @GiveWeapon 3 #MP5LNG 29 7000
return

:TEC9
0AB1: call_scm_func @GiveWeapon 3 #TEC9 32 7000
return

:CUNTGUN
0AB1: call_scm_func @GiveWeapon 3 #CUNTGUN 33 7000
return

:SNIPER
0AB1: call_scm_func @GiveWeapon 3 #SNIPER 34 3000
return

:NoWeapon
return

:GiveWeapon
Model.Load(0@)

while not Model.Available(0@)
 wait 0
end
01B2: give_actor $PLAYER_ACTOR weapon 1@ ammo 2@ 
Model.Destroy(1@)
0AB2: ret 0

{$I TestCheat.inc}

С использованием функции чита из этого сообщения.

Offline

#27 21-02-2009 11:20

Gyr
From: Серпухов
Registered: 03-02-2009
Posts: 246
Website

Re: Нажатие клавиш

После 03E5: text_box 'CHEAT1' удали строку while &0(0@,1i) == 0x41504F4E
и один из end'ов

Last edited by Gyr (21-02-2009 11:21)


Специально для тех, кто не умеет читать по английски. Мой ник читается как "ГИР"!!!
Народная мудрость:
Прежде чем задавать вопросы,ПОЧИТАЙ СПРАВКУ!!!!

Offline

#28 21-02-2009 14:29

GTASA
Registered: 13-09-2008
Posts: 476

Re: Нажатие клавиш

Спасибо, но после выбора оружия меню никак не убрать потом.

Offline

#29 21-02-2009 14:35

Seemann
Registered: 07-08-2006
Posts: 2,155

Re: Нажатие клавиш

@GTASA - Если ты про мою версию, то там все отлично убирается (Shift дает оружие, Enter просто закрывает меню)

Offline

#30 22-02-2009 04:30

GTASA
Registered: 13-09-2008
Posts: 476

Re: Нажатие клавиш

Нет, я бы не хотел ничего усложнять, мой пост адресован Gyr'y.

Offline

#31 25-02-2009 06:26

mfisto
From: Russia Perm
Registered: 01-02-2008
Posts: 558
Website

Re: Нажатие клавиш

to Seemann

а ты можешь написать скрипт который записывал бы введеныые символы в переменную @s или @v.


I know everything and nothing...

Offline

Board footer

Powered by FluxBB