Выделить актера под прицелом

FeniX-256 · 26-10-2009 13:03

Доброго всем времени суток! Подскажите пожалуйста, как реализовать, или ткните носом если уже было на форуме smile Вообщем, нужно прицепить актера под прицелом к переменной, для дальнейшей работы с самим актером.

Alien · 26-10-2009 20:54

Пример есть в Консоли Seemann'а
Приведу свой пример. Педы под прицелом подбрасываются вверх, а потом падают.:D

{$CLEO} 
0000:
while true 
    repeat
        wait 100
        0A8D: 0@ = read_memory 0xB6F3B8 size 4 virtual_protect 0
        if
            0@ == 0 
        then
            continue
        end
        0@ += 0x79C
        0A8D: 1@ = read_memory 0@ size 4 virtual_protect 0
    until 1@ <> 0
    0A8D: 2@ = read_memory 0xB74490 size 4 virtual_protect 0  //get pPedPool
    0AA8: call_function_method 0x4442D0 struct 2@ num_params 1 pop 0 ped 1@ store_to 0@   //get handle of ped
    0AA6: call_method 0x4637E0 struct 0xA90850 num_params 2 pop 0 type 2 ped 1@      //add references to ped

    if
        056D:   actor 0@ defined 
    then
        083C: set_actor 0@ velocity_in_direction_XYZ 0.0 0.0 100.0 
        actor.RemoveReferences(0@)
    end
end

Gyr · 27-10-2009 12:27

А вот это хороший скрипт!

mfisto · 27-10-2009 16:37

Что означает эта строка? поподробнее пожалуйста.

0AA6: call_method 0x4637E0 struct 0xA90850 num_params 2 pop 0 type 2 ped 1@      //add references to ped

Alien · 27-10-2009 18:31

mfisto wrote:

Что означает эта строка? поподробнее пожалуйста.
0AA6: call_method 0x4637E0 struct 0xA90850 num_params 2 pop 0 type 2 ped 1@      //add references to ped

Вообще, опкод 0AA6 вызывает процедуру-метод. А если конкретно, то эта строчка добавляет ссылку на педа в MissionCleanupList. 2 - это тип того, что добавляем (то есть пед), 1@ - то, что добавляем, 0xA90850 - ссылка на себя (MissionCleanupList), 0x4637E0 - адрес памяти этого метода. После этой операции педа можно назвать актером. То есть игра ни с того ни с сего не станет удалять его.

GTASA · 27-10-2009 22:14

Alien, я смотрю, ты спец по адресам памяти. Можешь как-нить сделать, чтобы снайперки тоже при джойпаде наводились на актера?

mfisto · 28-10-2009 09:32

Понятно, т.е это как бы тоже самое, если бы мы создали актера create actor вручную так. И актер становится неудаляемым, пока мы не сделаем remove reference. Или не так? Или он все равно исчезнет, например, на каком то расстоянии от игрока.

GTASA · 28-10-2009 11:13

А можно получить от вас адрес паияти, который удаляет из памяти информацию об актере? А то при Actor.Removereferences он начинает идти, а это мне совсем не нужно.

3Doomer · 28-10-2009 15:42

назначь переменной актёра любое другое значение (например, 0@ = 0)

mfisto · 28-10-2009 16:27

Назначить переменной ноль ничего не даст, т.к. мы просто этим самым теряем инфу переменной 0@ на ноль. Иначе говоря если у нас 0@ это число 67859403 то теперь оно будет ноль. И между прочим поправьте, если я не прав, что 0 это сам игрок, поэтому использовать ноль не в коем случае нельзя, а нужно -1.

3Doomer · 28-10-2009 16:37

а зачем тебе в последствии использовать переназначенную переменную как игрока? если твоя цель - удалить его из памяти...

mfisto · 28-10-2009 16:47

Так вот и получается, что это просто подмена, понимаешь. Из памяти надо не переменную освобождать, а сам объект. GTASA нужно чтоб актер перестал быть неудаляемым из памяти, но при этом это происходило незаметно для нашего виденья. И поэтому одной замены переменной тут не обойтись. Если она вообще нужна.

Den_spb · 28-10-2009 22:15

GTASA wrote:

А можно получить от вас адрес паияти, который удаляет из памяти информацию об актере? А то при Actor.Removereferences он начинает идти, а это мне совсем не нужно.

Removereferences удаляет информацию из памяти - и не нужны никакие манипуляции с переменными. А как сделать, чтобы пед не шел - это другая задача

Last edited by Den_spb (28-10-2009 22:30)

GTASA · 29-10-2009 09:25

Ладненько. А можно получить адресок памяти от вас, чтобы сделать актера неколлизированным, при этом чтобы он мог двигаться, бегать, прыгать...

3Doomer · 29-10-2009 09:31

не думаю, что возможно двигаться без коллизии)))

CrazyDude69 · 04-11-2009 23:00

А где вы адреса берете? Ладно адрес на денги, жизни, это можно с artmoney и другим редактором памяти найти, а координаты? И другие функции? Как вы вобще их находите? Кстате мне нужно записать в переменную машину, на которую я целюсь...

Alien · 08-11-2009 19:36

адреса ищутся путем анализом кода.
С машиной под прицелом сложнее. Над ней зеленых треугольников не появляется. Наверное надо перебирать все машины и определять возможность того, что в машину целится игрок.

Den_spb · 08-11-2009 19:58

Значок появляется, если прицеливаться самонаводящимся гранатомётом. Для других видов оружия может быть предложен вариант с опкодом no_obstacles - если известно направление прицеливания.

GTASA · 09-11-2009 07:58

А можно как-нибудь записать коорды, куда игрок целится, в переменную? Не важно, на машину, на актера, на землю. Хотя, было бы прекрасно, если можно получить координаты и на машине, и на актере.

Alien · 16-11-2009 16:36

немного подправил скрипт. Исправлены вылеты, когда актер в машине и появилась возможность получить хэндл целевого педа в режиме автоприцела.

{$CLEO} 
0000:
while true 
    wait 100
    if
        0AB1: call_scm_func @GetTargetedActor 0 store_to 0@ //IF and SET
    then
        if 
            003b: 1@ == 0@
        then
            continue
        end
        083C: set_actor 0@ velocity_in_direction_XYZ 0.0 0.0 100.0 
        actor.RemoveReferences(0@)
        0085: 1@ = 0@    //запоминаем "предыдущего"
    else
        1@ = 0
    end
end                

//0AB1: call_scm_func @GetTargetedActor 0 store_to 0@ //IF and SET
:GetTargetedActor
if
    not player.Defined(0)
then
    059A: return_false
    0AB2: ret 1 0
end
//проверить, находится ли пед в машине
0A96: 0@ = actor $PLAYER_ACTOR struct
0A8E: 1@ = 0@ + 0x58C
0A8D: 1@ = read_memory 1@ size 4 virtual_protect 0
if
    1@ <> 0
then
    059A: return_false
    0AB2: ret 1 0
end   
//получить цель актера (управление джойстиком)
0@ += 0x71C
0A8D: 1@ = read_memory 0@ size 4 virtual_protect 0
if
    1@ <> 0
then
    goto @Found
end
//получить цель актера (управление мышью)
0A8D: 0@ = read_memory 0xB6F3B8 size 4 virtual_protect 0
if
    0@ == 0
then
    059A: return_false
    0AB2: ret 1 0
end
0@ += 0x79C
0A8D: 1@ = read_memory 0@ size 4 virtual_protect 0
if
    1@ == 0
then
    059A: return_false
    0AB2: ret 1 0
end    
:Found
//если дошли до сюда, значит цель есть. Получаем хендл и добавляем референсы
0A8D: 2@ = read_memory 0xB74490 size 4 virtual_protect 0  //get pPedPool
0AA8: call_function_method 0x4442D0 struct 2@ num_params 1 pop 0 ped 1@ store_to 0@   //get handle of ped
//а вдруг там не актер был
if
    actor.Defined(0@)
then
    0AA6: call_method 0x4637E0 struct 0xA90850 num_params 2 pop 0 type 2 ped 1@      //add references to ped
    0485: return_true
    0AB2: ret 1 0@
else
    059A: return_false
    0AB2: ret 1 0
end

mfisto · 17-11-2009 11:29

Еще раз объясните тугодуму! smile

Т.е. добавляя в mission cleanup list, актера надо удалять потом, да? например remove reference.
А если не сделать так, то актер куда бы игрок не пошел не удалится из памяти.

Вопрос скорее к Alien'у

Alien · 17-11-2009 12:21

mfisto wrote:

Еще раз объясните тугодуму!
Т.е. добавляя в mission cleanup list, актера надо удалять потом, да? например remove reference.
А если не сделать так, то актер куда бы игрок не пошел не удалится из памяти.
Вопрос скорее к Alien'у

да. К этому приему следует относиться как к какому-нибудь опкоду для получения случайного актера (например, 089E). Получил актера, поработал с ним и почистил за собой.

Актер "не удалится из памяти" пока на него есть ссылка в mission cleanup list.

mfisto · 17-11-2009 12:51

И еще один вопрос возник
Eсть опкод
Actor.RemoveFromMissionCleanupList(1@)
После его применения нужно remove reference?

Alien · 17-11-2009 13:22

угум. Чой-то я запуталсо. Это ж оно и есть. Значит MissionCleanUpList - это только для thread'ов миссий. Но почему тогда игра не удаляет актеров для обычных трэдов? Наверное какой-то еще флаг есть...:rolleyes:

GTASA · 09-03-2010 11:27

А можете сотворить скрипт, чтобы получать переменную транспорта, на который направили прицел?

SannyBuilder.com Forums

#1 26-10-2009 13:03

Выделить актера под прицелом

#2 26-10-2009 20:54

Re: Выделить актера под прицелом

#3 27-10-2009 12:27

Re: Выделить актера под прицелом

#4 27-10-2009 16:37

Re: Выделить актера под прицелом

#5 27-10-2009 18:31

Re: Выделить актера под прицелом

#6 27-10-2009 22:14

Re: Выделить актера под прицелом

#7 28-10-2009 09:32

Re: Выделить актера под прицелом

#8 28-10-2009 11:13

Re: Выделить актера под прицелом

#9 28-10-2009 15:42

Re: Выделить актера под прицелом

#10 28-10-2009 16:27

Re: Выделить актера под прицелом

#11 28-10-2009 16:37

Re: Выделить актера под прицелом

#12 28-10-2009 16:47

Re: Выделить актера под прицелом

#13 28-10-2009 22:15

Re: Выделить актера под прицелом

#14 29-10-2009 09:25

Re: Выделить актера под прицелом

#15 29-10-2009 09:31

Re: Выделить актера под прицелом

#16 04-11-2009 23:00

Re: Выделить актера под прицелом

#17 08-11-2009 19:36

Re: Выделить актера под прицелом

#18 08-11-2009 19:58

Re: Выделить актера под прицелом

#19 09-11-2009 07:58

Re: Выделить актера под прицелом

#20 16-11-2009 16:36

Re: Выделить актера под прицелом

#21 17-11-2009 11:29

Re: Выделить актера под прицелом

#22 17-11-2009 12:21

Re: Выделить актера под прицелом

#23 17-11-2009 12:51

Re: Выделить актера под прицелом

#24 17-11-2009 13:22

Re: Выделить актера под прицелом

#25 09-03-2010 11:27

Re: Выделить актера под прицелом

Board footer