SannyBuilder.com Forums

robertom2002

Registered: 17-12-2009

Posts: 22

Need some help

Could anyone edit this image and write where's x y and z or - x -y and -z ?
I really need this....
http://tinypic.com/r/8yhtfp/6

And i have a problem ,when i want the actor to perform a animation in air ,and move 10 m forward .It moves but like a magnet ,if i turn around it still goes that location ,i mean it doesn't go in front of the player ,it goes in "the map" forward .I don't know how to explain it .
How to move the actor forward ? like
if and
key pressed...
actor in air
as actor perform animation.....
set velocity to  (i want to always go forward but i can't )

Hep please with both of these ,really need it

Den_spb

From: Ленинград

Registered: 23-11-2008

Posts: 941

Website

Re: Need some help

World axis: X - from west to east, Y - from south to north, Z - from ground to sky.

robertom2002

Registered: 17-12-2009

Posts: 22

Re: Need some help

Thank you ,could you also help me with the second one please ,or anyone here?

ZAZ

Registered: 05-12-2007

Posts: 55

Re: Need some help

And i have a problem ,when i want the actor to perform a animation in air ,and move 10 m forward .It moves but like a magnet ,if i turn around it still goes that location ,i mean it doesn't go in front of the player ,it goes in "the map" forward .I don't know how to explain it .
How to move the actor forward ? like
if and
key pressed...
actor in air
as actor perform animation.....
set velocity to  (i want to always go forward but i can't )

Hep please with both of these ,really need it

the opcode 083C: set_actor $PLAYER_ACTOR velocity_in_direction_XYZ 5@ 6@ 8@
don't requires coords of world-axis as xyz-param
and also not offset-values in relation to player axis
it requires a mix of both

test the airswim script below
press backspace to start airswim
use arrow keys forward, left, right to steer

{$CLEO .cs}
:Airswim2
03A4: name_thread 'AirMV' 

018A: 29@ = create_checkpoint_at -2026.1396 138.857 28.8
0165: set_marker 29@ color_to  0

:Airswim2_01
0001: wait  0 ms
00D6: if  0
0256:   player $PLAYER_CHAR defined
004D: jump_if_false @Airswim2_01
00D6: if 0
0AB0:   key_pressed 8
004D: jump_if_false @Airswim2_01

04ED: load_animation "SWIM" 

:Airswim2_03
0001: wait  0 ms
if
04EE:   animation "SWIM" loaded
004D: jump_if_false @Airswim2_03
083C: set_actor $PLAYER_ACTOR velocity_in_direction_XYZ 0.0 0.0 50.0
0001: wait  1000 ms
0812: unknown_action_sequence $PLAYER_ACTOR "Swim_Breast" from_file "SWIM"  1.0  1  1  1  1 -2

:Airswim2_05
0001: wait  0 ms
00D6: if  0
0256:   player $PLAYER_CHAR defined
004D: jump_if_false @Airswim2_05
0172: 30@ = actor $PLAYER_ACTOR z_angle
0007: 4@ =  1.0  // floating-point values
0007: 8@ =  1.0  // floating-point values
if
00E1:   key_pressed 0 6  
004D: jump_if_false @Airswim2_07
0007: 8@ =  5.0  // floating-point values

:Airswim2_07
00D6: if 0 
0AB0:   key_pressed 39
004D: jump_if_false @Airswim2_08
0172: 30@ = actor $PLAYER_ACTOR z_angle
000F: 30@ -=  8.5  // floating-point values
0173: set_actor $PLAYER_ACTOR z_angle_to  30@
0002: jump @Airswim2_09

:Airswim2_08
00D6: if 0
0AB0:   key_pressed 37
004D: jump_if_false @Airswim2_09
0172: 30@ = actor $PLAYER_ACTOR z_angle
000B: 30@ +=  8.5  // floating-point values
0173: set_actor $PLAYER_ACTOR z_angle_to  30@
0002: jump @Airswim2_09

:Airswim2_09
if
0AB0:   key_pressed 38  
004D: jump_if_false @Airswim2_010
0007: 4@ =  20.0  // floating-point values
0002: jump @Airswim2_010



:Airswim2_010
02F6: 5@ = cosine 30@  // sinus swapped with cosine
02F7: 6@ = sinus 30@ // cosine swapped with sinus 
006B: 5@ *= 4@  // floating-point values
006B: 6@ *= 4@  // floating-point values
0013: 5@ *=  -1.0  // floating-point values
083C: set_actor $PLAYER_ACTOR velocity_in_direction_XYZ 5@ 6@ 8@

if  and
8AB0:   not key_pressed 8
0611:  actor $PLAYER_ACTOR animation == "Swim_Breast" 
004D: jump_if_false @Airswim2_13
0002: jump @Airswim2_05

:Airswim2_13
0792: disembark_instantly_actor $PLAYER_ACTOR
04EF: release_animation "SWIM"
0001: wait  1000 ms
0002: jump @Airswim2_01