#1 24-02-2012 18:43

Vital
From: Москва
Registered: 07-11-2010
Posts: 64
Website

Проблема с коронами

Создал скрипт, попытался в нем создать несколько корон, вроде все правильно, но короны не создаются. Я пытался сделать их создание в цикле, но результат тот же - корон нету. Может, кто-нибудь подскажет, как правильно создать короны в данном скрипте?

Вот код:

:Time
wait 0
if and
not actor.Dead($PLAYER_ACTOR)
not actor.Driving($PLAYER_ACTOR)
0ADC: test_cheat "TIME"
jf @Time
03BF: set_player $PLAYER_CHAR ignored_by_everyone 1
actor.LockInCurrentPosition($PLAYER_ACTOR,1)
04C4: store_coords_to 1@ 2@ 3@ from_actor $PLAYER_ACTOR with_offset 0.0 3.0 0.7
04C4: store_coords_to 4@ 5@ 6@ from_actor $PLAYER_ACTOR with_offset 1.0 3.0 0.7 
04C4: store_coords_to 7@ 8@ 9@ from_actor $PLAYER_ACTOR with_offset -1.0 3.0 0.7  
052C: set_player $PLAYER_CHAR drunk_visuals 50
for 15@ = 0 to 35
024F: create_corona_with_radius 0.4 type 1 lensflares 1 with_color 255 255 255 at 1@ 2@ 3@
024F: create_corona_with_radius 0.4 type 1 lensflares 1 with_color 255 255 255 at 4@ 5@ 6@
024F: create_corona_with_radius 0.4 type 1 lensflares 1 with_color 255 255 255 at 7@ 8@ 9@
wait 100
end
wait 500 
0169: set_fade_color_RGB 255 255 255 
fade 0 250
wait 500
0110: clear_player $PLAYER_CHAR wanted_level 
0209: 10@ = random_int_in_ranges 0 10
052C: set_player $PLAYER_CHAR drunk_visuals 0 
if
10@ > 5
then
0209: 11@ = random_int_in_ranges 1 6
010D: set_player $PLAYER_CHAR wanted_level_to 11@
else
0209: 12@ = random_int_in_ranges 5 25
0851: set_actor $PLAYER_ACTOR decrease_health_by 12@ flag 0 
end
0209: 13@ = random_int_in_ranges 1 23
0209: 14@ = random_int_in_ranges 1 55
00C0: set_current_time_hours_to 13@ minutes_to 14@ 
wait 500
0395: clear_area 1 at 1@ 2@ 3@ radius 325.0 
0169: set_fade_color_RGB 0 0 0 
fade 1 250
wait 500
03BF: set_player $PLAYER_CHAR ignored_by_everyone 0
actor.LockInCurrentPosition($PLAYER_ACTOR,0) 
wait 35000
jump @Time

Заранее благодарю за помощь!

Offline

#2 25-02-2012 15:14

Den_spb
From: Ленинград
Registered: 23-11-2008
Posts: 937
Website

Re: Проблема с коронами

Корона отрисовывается только один раз. Поэтому между двумя последовательными вызовами команды создания короны должен выполняться не более, чем один wait X, где X = 0 (или 5, 10, но не 100 - иначе короны будут рисоваться "через раз" и станут "моргать" или вообще будут невидимы).

Это относится и к другим "одноразовым" объектам - проекциям света, флешлайтам и т.д.
Пример: создадим источник света у гаража СФ, состоящий из трёх компонентов - корона, флешлайт и проекция света.

{$CLEO}
wait 0
while true
    wait 0
    09E5: create_flash_light_at -2015.9216 144.8292 28.0 RGB_mask 0 0 255 radius 5.0
    04D5: create_corona_at -2015.9216 144.8292 28.0 radius 0.7 type 0 flare 0 RGB 0 0 255 
    016F: create_particle 3 rotation_factor 3.14 size 1.5 intensity 255 flags 0 0 255 at -2015.9216 144.8292 28.0 
end

Last edited by Den_spb (25-02-2012 15:31)

Offline

#3 25-02-2012 18:52

Vital
From: Москва
Registered: 07-11-2010
Posts: 64
Website

Re: Проблема с коронами

@Den_spb - спасибо большое! Теперь все работает. Не знал, что задержка должна быть небольшой.

Offline

Board footer

Powered by FluxBB