SannyBuilder.com Forums

Seemann

Registered: 07-08-2006

Posts: 2,158

2025 - Кто тут?

---

CLEO Library • Sanny Builder 4 • Разработка Sanny Builder • Документация по моддингу GTA

Vital

From: Москва

Registered: 07-11-2010

Posts: 66

Website

Re: 2025 - Кто тут?

Я! Надеюсь, кто-нибудь ещё подтянется. А пока кину сюда свой скрипт снежка, протестирую подсветку. Да и вообще вспомню, каково это, на форумах писать.

{$CLEO} //  Script by Vital (Vitaly Pavlovich Ulyanov)
script_name 'SNOW'

const minStartX = 10.0
const maxStartX = 630.0
const minStartY = -15.0
const maxStartY = -350.0

int i // `for` loop counter
int snow = 0 // Snow activation flag
float x[10] // X positions of snowflakes
float y[10] // Y positions of snowflakes
float mx, my // Mouse X and Y offsets

while true
    wait 0
    
    if not Player.IsPlaying(0)
    then continue
    end
    
    if Pad.TestCheat("SNOW")
    then
        if snow == 0
        then
            snow = 1
            for i = 0 to 9 // Reset snowflakes position to random starting points
                x[i] = Math.RandomFloatInRange(minStartX, maxStartX)
                y[i] = Math.RandomFloatInRange(minStartY, maxStartY)
            end
            Text.PrintStringNow("Snow ~r~ON~s~ [Script by ~y~Vital~s~]", 3000)
        else
            snow = 0
            Text.PrintStringNow("Snow ~r~OFF", 3000)
        end
    end
    
    if snow == 1
    then
        for i = 0 to 9
            // X coordinate is the value of sine function
            mx, my = Mouse.GetMovement()
            float s = Math.Sin(y[i])
            float ms = Math.Sin(mx)
            // A bit of randomisation for both X and Y movement
            float r = Math.RandomFloatInRange(0.25, 0.7)
            float ySpeed = Math.RandomFloatInRange(0.3, 0.5)
            s *= r
            s += ms
            
            // Timed (fps-independent) addition
            x[i] +=@ s
            y[i] +=@ ySpeed
            
            if and // Current snowflake is not ouf of borders
                y[i] < 448.0
                x[i] > 0.0
                x[i] < 640.0
            then
                if y[i] > -10.0
                then
                    Text.UseCommands(true)
                    Text.SetScale(0.4, 1.8)
                    Text.SetDropshadow(1, 0, 148, 255, 150)
                    Text.Display(x[i], y[i], "PAGE_00")
                    Text.UseCommands(false)
                end
            else // Reset snowflake's position to a random starting point
                x[i] = Math.RandomFloatInRange(minStartX, maxStartX)
                y[i] = Math.RandomFloatInRange(minStartY, maxStartY)
            end
        end
    end
end

P.S. Не хватает новой подсветки синтаксиса. Но это всё со временем придёт, а пока хватает или SCM, или CPP.
P.P.S. Немного соскучился по длинным осмысленным сообщениям. Форумы к ним подталкивают получше, а то вот
такая
манера
писать
тексты
уже порядком
за-
дол-
ба-
ла
.

---

YouTube
Телеграм

Seemann

Registered: 07-08-2006

Posts: 2,158

Re: 2025 - Кто тут?

Это да. Для тех, кто пропустил последние лет пять, краткий список основных событий.

• Новая полная база опкодов https://library.sannybuilder.com/

• Sanny Builder апнулся до версии 4.

• CLEO апнулась до версии 5

• В сети пролетали исходники GTA V и частично San Andreas.

• На гитхабе можно найти полностью отревершенный код III и VC, а также частично отревершенный San Andreas.

• Вместе с выходом ремастеров трилогии были выложены полные исходники скриптов всех игр, с комментариями создателей.

• Вышел CLEO Redux с поддержкой языка JavaScript для всей трилогии и кучи других игр.

---

CLEO Library • Sanny Builder 4 • Разработка Sanny Builder • Документация по моддингу GTA

Vital

From: Москва

Registered: 07-11-2010

Posts: 66

Website

Re: 2025 - Кто тут?

По привычке из Discord’а хотел нажать «Ответить» или поставить реакцию. Надо переучиваться обратно. 

А ещё надо обязательно упомянуть разрабатываемый Seemann’ом новый компилятор Somersault, доступный как на сайте, так и в Sanny Builder 4 в качестве отдельного режима редактирования. С интересом слежу за его развитием и надеюсь на ещё большую поддержку SB4. 

P.S. Если форумы будут оживляться дальше, надо и часовые пояса обновить, а то мне для соответствия пришлось Африку поставить.

Last edited by Vital (27-04-2025 17:32)

---

YouTube
Телеграм