Помогите с миссией

grand · 31-08-2008 09:07

:MISSION1
0000: NOP 
0001: wait 0 ms 
03A4: name_thread 'MISSION1' 
0004: $ONMISSION = 1 
0050: gosub @MISSION1_74 
00D6: if 
0112:   wasted_or_busted // mission only 
004D: jump_if_false @MISSION1_59 
0050: gosub @MISSION1_418 

:MISSION1_59
0001: wait 0 ms 
0004: $ONMISSION = 0 
00D8: mission_cleanup 
004E: end_thread 

:MISSION1_74
0001: wait 0 ms 
0247: load_model #FAM1 
0247: load_model #MICRO_UZI 
0247: load_model #ADMIRAL
038B: load_requested_models 

:MISSION1_90
0001: wait 0 ms 
00D6: if and
0248:   model #FAM1 available 
0248:   model #MICRO_UZI available 
0248:   MODEL #ADMIRAL available
004D: jump_if_false @MISSION1_90 
0001: wait 0 ms 
00A5: 1@ = create_car #ADMIRAL at 2508.496 -1673.078 13.3795 
0175: set_car 1@ Z_angle_to 353.4433 
009A: 2@ = create_actor_pedtype 8 model #FAM1 at 2522.668 -1678.886 15.497 
0173: set_actor 2@ Z_angle_to 75.8508 
0001: wait 0 ms 
054A: set_actor 2@ immune_to_car_headshots 1 
054A: set_actor $PLAYER_ACTOR immune_to_car_headshots 1 
01B2: give_actor $PLAYER_ACTOR weapon 28 ammo 30000 // Load the weapon model before using this 
05CA: AS_actor $PLAYER_ACTOR enter_car 1@ passenger_seat 0 10000 ms 
0221: set_player $PLAYER_ACTOR trapped_in_car 1 
05D1: AS_actor 2@ drive_car 1@ to 1395.009 456.8759 20.1303 speed 15.0 0 model #NULL 0 
0464: put_actor $PLAYER_ACTOR into_turret_on_car 1@ at_car_offset -1.0 0.1 0.7 position 0 shooting_angle_limit 270.0 with_weapon 28 
00D6: if 
0118:   actor 2@ dead 
004D: jump_if_false @MISSION1_324 
0002: jump @MISSION1_418 

:MISSION1_324
00D6: if 
01B0:   car 1@ sphere 0 in_sphere 1395.009 456.8759 20.1303 radius 4.0 4.0 4.0 stopped 
004D: jump_if_false @MISSION1_324 
0002: jump @MISSION1_379 

:MISSION1_379
0001: wait 0 ms 
01E3: show_text_1number_styled GXT 'M_PASSD' number 0 time 5000 style 1  // MISSION PASSED!
0394: play_music 1 
030C: progress_made += 1 
0008: $NEW_TOTAL_PASSED_MISSIONS += 1
0221: set_player $PLAYER_ACTOR trapped_in_car 0 
0051: return 

:MISSION1_418
0001: wait 0 ms 
00BA: show_text_styled GXT 'M_FAIL' time 5000 style 1  // ~r~MISSION FAILED!
004F: create_thread @START 
0051: return

Last edited by grand (31-08-2008 09:32)

VcSaJen · 31-08-2008 09:58

Чем помочь-то?

В цикле

:MISSION1_324
00D6: if 
01B0:   car 1@ sphere 0 in_sphere 1395.009 456.8759 20.1303 radius 4.0 4.0 4.0 stopped 
004D: jump_if_false @MISSION1_324

ты не поставил задержку (wait 0):

:MISSION1_324
0001: wait 0
00D6: if 
01B0:   car 1@ sphere 0 in_sphere 1395.009 456.8759 20.1303 radius 4.0 4.0 4.0 stopped 
004D: jump_if_false @MISSION1_324

Что-бы узнать, где именно зависла игра, поставь Cleo-плагин SCMLog
(SB3\tools\CLEO3\plugins\scmlog\scmlog.cleo и scmlog.ini скопируй в GTA-SanAndreas\cleo), после зависания смотришь последний опкод в файле cleo\scmlog.log.P.S. Не надо каждый раз декомпилировать, просто открывай текстовый исходник

Last edited by VcSaJen (31-08-2008 10:18)

VcSaJen · 31-08-2008 12:10

Также надо заменить

05D1: AS_actor 2@ drive_car 1@ to 1395.009 456.8759 20.1303 speed 15.0 0 model #NULL 0

на

05CA: AS_actor 2@ enter_car 1@ passenger_seat 0 10000 ms
02C2: car 1@ drive_to 1395.009 456.8759 20.1303
00AE: set_car 1@ traffic_behaviour_to 3 
00AD: set_car 1@ max_speed_to 15.0

машина должна ехать по дорогам к месту назначения. Но только в пределах одного города. У тебя место назначения - Red Country, а машина выезжает из Лос Сантоса. Попробуй разбить на две части. Также надо сделать проверку, в иашине ли игрок и актёр и только потом отправлять машину. И ещё: нет затемнения экрана, телепорта игрока к машине, "заморозки" игрока на время, пока он идёт к машине.

Jabhacksoul · 04-09-2008 05:27

Извините мой бедный языка я использую переводчика, и я знаю только английский и плохой английский
grin

Я также работающих на получение автомобиля переходить от точки к точке Вместе с тем он не продвигаемся очень быстро. Я медленно сцена погони в мире. Вот мой код:

100@ = 0

:MISSN_01_300 //The Chase
if
100@ == 0
then
//00A9: set_car $pen_bike to_normal_driver              
00A7: car $pen_bike drive_to 1529.666 -1723.537 12.982
100@ += 1
end
if and
100@ == 1
00EE:   actor $ACTOR_ONE 0 near_point 1529.666 -1723.537 radius 3.0 3.0 in_car 
then
00A7: car $pen_bike drive_to 1559.0425 -1734.7759 13.4115
100@ += 1
end
if and
100@ == 2
00EE:   actor $ACTOR_ONE 0 near_point 1559.0425 -1734.7759 radius 3.0 3.0 in_car  
then
00A7: car $pen_bike drive_to 1603.7103 -1735.0493 13.4166
100@ += 1
end
if and
100@ == 3
00EE:   actor $ACTOR_ONE 0 near_point 1603.7103 -1735.0493 radius 3.0 3.0 in_car  
then
00A7: car $pen_bike drive_to  1611.5042 -1643.5729 13.5743
Car.SetDriverBehaviour($pen_bike 2) // This is where I need him to speed up and runaway but 2 is wrong
100@ += 1
end
if and
100@ == 4
00EE:   actor $ACTOR_ONE 0 near_point 1611.5042 -1643.5729 radius 3.0 3.0 in_car  
then
00A7: car $pen_bike drive_to  1624.9291 -1761.4268 3.9848
100@ += 1
end
if and
100@ == 5
00EE:   actor $ACTOR_ONE 0 near_point 1624.9291 -1761.4268 radius 3.0 3.0 in_car  
then
00A7: car $pen_bike drive_to 1864.3685 -1825.6257 4.0136
100@ += 1
end 
if and
100@ == 6
00EE:   actor $ACTOR_ONE 0 near_point 1864.3685 -1825.6257 radius 3.0 3.0 in_car  
then
00A7: car $pen_bike drive_to 1928.6847 -1830.8815 6.5482
100@ += 1
end 
if and
100@ == 7
00EE:   actor $ACTOR_ONE 0 near_point 1928.6847 -1830.8815 radius 3.0 3.0 in_car  
then
00A7: car $pen_bike drive_to 2017.9768 -1848.902 4.0139 
100@ += 1
end 
if and
100@ == 8
00EE:   actor $ACTOR_ONE 0 near_point 2017.9768 -1848.902 radius 3.0 3.0 in_car  
then
00A7: car $pen_bike drive_to 2301.5574 -1863.9248 0.0083 
100@ += 1
end 
if and
100@ == 9
00EE:   actor $ACTOR_ONE 0 near_point 2301.5574 -1863.9248 radius 3.0 3.0 in_car  
then
00A7: car $pen_bike drive_to 2355.6921 -1874.6003 9.2955 
100@ += 1
end 
if and
100@ == 10
00EE:   actor $ACTOR_ONE 0 near_point 2355.6921 -1874.6003 radius 3.0 3.0 in_car  
then
00A7: car $pen_bike drive_to 2591.3303 -1859.0563 3.895 
100@ += 1
end

Спасибо за Вашу помощь.

Last edited by Jabhacksoul (04-09-2008 05:29)

VcSaJen · 04-09-2008 05:49

Попробуй/try:

00AE: set_car 71@ traffic_behaviour_to 2 
00AD: set_car 36@ max_speed_to 35.0

Jabhacksoul · 04-09-2008 11:39

Thanks I will be sure to give that a try.
Спасибо я буду уверен, что дать попробовать.
-----edited--------
Update for you. I found using scmpath worked much better. My chase scene now runs fast and action packed. Here is how to use the code:

Обновление для вас. Я нашел с помощью scmpath работал гораздо лучше. Моя сцена погони в настоящее время проходит быстро и действия упакованы. Вот как использовать код:

100@ = 0

:MISSN_01_300 //The Chase
if
100@ == 0
then
    gosub @MISSN_01_310
    100@ = 1
end
if and
100@ == 1
00EE:   actor $ACTOR_ONE 0 near_point 1616.8341 -1708.2432 radius 5.0 5.0 in_car 
then
    gosub @MISSN_01_320
    100@ += 1
end
if and
100@ == 2
00EE:   actor $ACTOR_ONE 0 near_point 1833.2645 -1817.8071 radius 5.0 5.0 in_car 
then
    gosub @MISSN_01_330
    100@ += 1
end
return

:MISSN_01_310
05D6: clear_scmpath 
05D7: add_point_to_scmpath 1527.5897 -1719.1304 13.4296
05D7: add_point_to_scmpath 1555.2362 -1734.1617 13.4124
05D7: add_point_to_scmpath 1603.719 -1734.9719 13.4136
05D7: add_point_to_scmpath 1609.3877 -1653.957 13.5762 
05D7: add_point_to_scmpath 1615.4048 -1663.8196 13.5589
05D7: add_point_to_scmpath 1616.8341 -1708.2432 4.4613
06BB: set_actor $ACTOR_ONE drive_car $pen_bike speed 15.0 along_SCM_path
return

:MISSN_01_320
05D6: clear_scmpath 
05D7: add_point_to_scmpath 1624.8857 -1767.3146 3.9915
05D7: add_point_to_scmpath 1833.2645 -1817.8071 4.0138
06BB: set_actor $ACTOR_ONE drive_car $pen_bike speed 35.0 along_SCM_path
0672: AS_actor $ACTOR_TWO attack_car $pen_bike
return

:MISSN_01_330
05D6: clear_scmpath
05D7: add_point_to_scmpath 1925.098 -1830.64 5.7598
05D7: add_point_to_scmpath 1970.4095 -1837.9246 4.1215
05D7: add_point_to_scmpath 2058.146 -1852.7108 4.025
05D7: add_point_to_scmpath 2231.0232 -1847.6094 0.2432
05D7: add_point_to_scmpath 2231.0232 -1847.6094 0.2432 
05D7: add_point_to_scmpath 2357.467 -1875.3892 9.2914 
05D7: add_point_to_scmpath 2484.9414 -1874.5491 9.3438
05D7: add_point_to_scmpath 2596.6501 -1857.2941 3.7431
06BB: set_actor $ACTOR_ONE drive_car $pen_bike speed 50.0 along_SCM_path 
return

The scmpath seems to hold about 10 points. The prey will sometimes get stuck so many checkpoints are needed with clear line of sight between them.

Scmpath-видимому, проведет около 10 баллов. Хищных иногда застревают многие контрольно-пропускные пункты необходимы четкие линии прямой видимости между ними.

Если бы я оставлять этот вопрос я начну говорить русский язык. lol

Last edited by Jabhacksoul (05-09-2008 15:03)

SannyBuilder.com Forums

#1 31-08-2008 09:07

Помогите с миссией

#2 31-08-2008 09:58

Re: Помогите с миссией

#3 31-08-2008 12:10

Re: Помогите с миссией

#4 04-09-2008 05:27

Re: Помогите с миссией

#5 04-09-2008 05:49

Re: Помогите с миссией

#6 04-09-2008 11:39

Re: Помогите с миссией

Board footer