Один вопрос

GTASA · 04-04-2009 11:52

Скажите плиз как можно запустить миссию какую-нибудь? Например просто где-нить жмем кнопку и запускается миссия с катсценой или без.

Gyr · 04-04-2009 19:20

@GTASA -
start_mission 1@, где 1@-номер миссии, который берется в начале MAIN.SCM

[on_DIM_on] · 06-04-2009 15:08

Не подскажите и покажите) как увеличить количество цветов в панели $CARMOD_MENU_COLORS

Sw[ee]t · 08-04-2009 05:42

А смысл? Там и так все цвета которые доступны в игре вообще (как-то так)

[on_DIM_on] · 08-04-2009 09:41

Sw[ee]t wrote:

А смысл? Там и так все цвета которые доступны в игре вообще (как-то так)

Там не все цвета(, а примерно половина

Gyr · 08-04-2009 16:17

Существует ли способ добавления новых иконок (не замены, а именно добавления!!!) на радар? И желательно что-бы они дружили с опкодом 0570: $ICON = create_asset_radar_marker_with_icon 31 at x y z
. Я имею ввиду ,что бы им присваивался собственный номер как в таблице иконок.

mfisto · 09-04-2009 18:15

Кто хорошо знает структуру тачек, подскажите есть ли в ней какое нибудь неиспользуемое незанятое смещение, или придется через вылеты игры все проверять.

GTASA · 12-04-2009 13:53

Ребята, скажите пожалуйста, как завербовать педов из определенной группы, например, копов?

mfisto · 13-04-2009 18:44

to GTASA

мне об этом уже говорили и подсказывали, посмотри вот эту тему, внимательно!

http://sannybuilder.com/forums/viewtopic.php?id=75

Driver · 13-04-2009 23:46

Всем прет! Вообщем я делаю скрипт угона любых тачек на гф моде, вот пока что получилось(На гф моде выкидывает из тачки если например гражданский залез в гидру пишет что он не состоит в таких органах и игрок автоматически вылазиет):
:1
wait 250
if
Player.Defined($PLAYER_CHAR)
not Actor.Driving($PLAYER_ACTOR)
jf @1
0AB5: store_actor $PLAYER_ACTOR closest_vehicle_to 2@ closest_ped_to 1@
if
056E: car 2@ defined
0AB0: key_pressed 35 //end
jf @1
072A: put_actor $PLAYER_ACTOR into_car 2@ driverseat
Actor.InCar($PLAYER_ACTOR, 2@)
018C: play_sound 1058 at 0.0 0.0 0.0
jump @1
С закрытыми тачками проблем нету, всё прекрасно рабит, но когда залазию в служебную всё равно вылазиет) Подскажите есть какой нить опкод что бы заморозить актера в тачке которой он сидит и ей можно было бы управлять в дальнеишем?)

Last edited by Driver (14-04-2009 01:54)

XotaBi4b · 14-04-2009 08:46

Driver пробуй 0526: set_actor $PLAYER_ACTOR stay_in_car 1

Интересный опкод 0638: AS_actor 429@ stay_put 1, незнаю за что он отвечает, но можешь его тоже попробовать.

Добавляй по одному после 072A: put_actor $PLAYER_ACTOR into_car 2@ driverseat А ещё лучше замени на 036A: put_actor $PLAYER_ACTOR in_car 2@ и затем зделай stay.

Alien · 14-04-2009 15:58

еще надо вытащить Player.Defined($PLAYER_CHAR) в отдельную проверку. Там вроде как что-то с чем-то конфликтует.
То есть надо писать вот так:

...
if
Player.Defined($PLAYER_CHAR)
jf @1
if
not Actor.Driving($PLAYER_ACTOR)
jf @1

Опкод Actor.InCar($PLAYER_ACTOR, 2@) повис ни к селу ни к городу. Это же проверка.

Driver wrote:

Подскажите есть какой нить опкод что бы заморозить актера в тачке которой он сидит и ей можно было бы управлять в дальнеишем?)

0526: set_actor $PLAYER_ACTOR stay_in_car 1 - ты это искал?

Driver · 14-04-2009 16:48

Alien wrote:

еще надо вытащить Player.Defined($PLAYER_CHAR) в отдельную проверку. Там вроде как что-то с чем-то конфликтует.
То есть надо писать вот так:
...
if
Player.Defined($PLAYER_CHAR)
jf @1
if
not Actor.Driving($PLAYER_ACTOR)
jf @1
Опкод Actor.InCar($PLAYER_ACTOR, 2@) повис ни к селу ни к городу. Это же проверка.
Driver wrote:
Подскажите есть какой нить опкод что бы заморозить актера в тачке которой он сидит и ей можно было бы управлять в дальнеишем?)
0526: set_actor $PLAYER_ACTOR stay_in_car 1 - ты это искал?

Спасибо всем за ответы!=)
Я попробовал, но не помогло. Из тачки всё равно вылазиет.
Дописал скрит так:

0000:
:PRIVETREBYATA
wait 250
if
Player.Defined($PLAYER_CHAR)
jf @PRIVETREBYATA
if
not Actor.Driving($PLAYER_ACTOR)
jf @PRIVETREBYATA
0AB5: store_actor $PLAYER_ACTOR closest_vehicle_to 2@ closest_ped_to 1@
if
056E:   car 2@ defined 
0AB0:  key_pressed 35 //end
jf @PRIVETREBYATA
036A: put_actor $PLAYER_ACTOR in_car 2@
0526: set_actor $PLAYER_ACTOR stay_in_car 1
018C: play_sound 1058 at 0.0 0.0 0.0
jump @PRIVETREBYATA2

:PRIVETREBYATA2
Wait 250
if
 Actor.Driving($PLAYER_ACTOR)
else_jump @PRIVETREBYATA
0AB0:  key_pressed 35 //end
jf @PRIVETREBYATA2
0526: set_actor $PLAYER_ACTOR stay_in_car 0
0622: AS_unknown_remove_actor $PLAYER_ACTOR from_car $2
018C: play_sound 1058 at 0.0 0.0 0.0
jump @PRIVETREBYATA

Я хотел добавить что бы если на End нажать в тачке что бы вылез, но почему то кикает когда End в тачке нажимаю. В чем может быть ошибка?
Так же я нашел одно решение что бы оставаться в тачке:

072A: put_actor $PLAYER_ACTOR into_car 2@ driverseat
wait 250
072A: put_actor $PLAYER_ACTOR into_car 2@ driverseat

Если залезть в тачку и нажать на паузу, подождав несколько сек, то он остается в тачке, но хотелось бы сделать так что бы не пришлось ее нажимать=)

Last edited by Driver (14-04-2009 16:49)

mfisto · 15-04-2009 05:44

to Driver

Игрока нельзя заставить остаться в машине, если на него действуют в этот момент другие опкоды высадки, или игрок не на мотике. На мотике stay_in_bike срабатывает. По другому никак. Можно еще цикл поставить чтобы игрок все время в тачку помещался put_in_car, но управлять ей будет тогда нельзя.

Gyr · 15-04-2009 10:55

Попробуй сесть в тачку на место пассажира и взять над этой тачкой RC управление.

Driver · 15-04-2009 22:28

Ясно с этим я разобрался спасибо всем!) Вот ещё вопрос: Какой опкод можно использовать что бы тачка сама ехала когда я сижу за рулём, но ехала не в указанные кординаты а просто каталась?) Я хочу добавить в скрипт автодраивера(указываешь маркер на карте и тача сама туда едет) такую функцию что бы тачка сама каталась) Вот как это я пытался сделать:

:BODY2
wait 0
if
Player.Defined($PLAYER_CHAR)
jf @AD_1
if
Player.Controllable($PLAYER_CHAR)
jf @AD_1
if
Actor.Driving($PLAYER_ACTOR)
jf @AD_1
IF
0AB0: key_pressed 111
Then
018C: play_sound 1058 at 0.0 0.0 0.0
072A: put_actor $PLAYER_ACTOR into_car 0@ driverseat
00AE: set_car 0@ traffic_behaviour_to 2
0423: set_car 0@ improved_handling_to 2 // (float)
00AE: unknown_set_car 0@ to_ignore_traffic_lights 2
01EC: make_car 0@ very_heavy 1
Car.SetMaxSpeed(0@, $max_speed)
Car.SetDriverBehaviour($0,1)
end
jump @BODY

Но почему-то при нажатии / ничего не происходит!=) Какой опкод можно сюды втулить что бы тача каталась по городу?) Заранее спасибо)

Seemann · 16-04-2009 04:51

Зачем у тебя

072A: put_actor $PLAYER_ACTOR into_car 0@ driverseat

если предполагается, что игрок уже в машине (Actor.Driving($PLAYER_ACTOR))?)

Откуда берется машина в переменной 0@?
Чему равна переменная $max_speed?
Почему в Car.SetDriverBehaviour($0,1) используется глобальная переменная $0 вместо 0@?

Ах да, и где собственно сама команда машине "ехать в определенную точку" (drive_to)?

Ответишь на эти вопросы - получишь работающий код smile

Last edited by Seemann (16-04-2009 05:00)

Sw[ee]t · 16-04-2009 16:32

Решил сделать мини-скрипт при нажатии "Беседа - Нет" радио выключалось, при повторном нажатии - включалось с той станции на которой был до этого smile . Не работает вообще.
Желательно ещё на кнопочку X назначить smile

{$CLEO .cs}


// ------- Main -------
0000:


:TURNOF
thread "TURNOF"
0@ = 0

:TURNOF_1
wait 0 ms
if and
  0@ == 0
  Actor.Driving($PLAYER_ACTOR)
  00E1: key_pressed 0 10 // VK_NO
jf @TURNOF_2
0@ = 1
051E: 1@ = get_current_radio_station
wait 500
041E: set_radio_station 12
jump @TURNOF_1 

:TURNOF_2
wait 0 ms
if and
  0@ == 1
  Actor.Driving($PLAYER_ACTOR)
  00E1: key_pressed 0 10 // VK_NO
jf @TURNOF_1
0@ = 0
041E: set_radio_station 1@
jump @TURNOF_2

mfisto · 17-04-2009 10:09

вот так сто пудей работает проверено:

// This file was decompiled using sascm.ini published by Seemann (http://sannybuilder.com/files/SASCM.rar) on 06.11.2008

{$VERSION 3.1.0030}
{$CLEO .cs}

//-------------MAIN---------------
thread "TURNOF"

:TURNOF_1
wait 0 ms
if 
   Player.Defined($PLAYER_CHAR)
jf @TURNOF_1a
if
   Actor.Driving($PLAYER_ACTOR)
jf @TURNOF_1a
if
00E1:   player 0 pressed_key 10 
jf @TURNOF_1b
if
88B7:   not test 0@ bit 1    
jf @TURNOF_1
if
88B7:   not test 0@ bit 0   
jf @TURNOF_2
051E: 1@ = get_current_radio_station
041E: set_radio_station 12
08BD: set 0@ bit 0
08BD: set 0@ bit 1
jump @TURNOF_1 

:TURNOF_1a
08C3: clear 0@ bit 0 

:TURNOF_1b
08C3: clear 0@ bit 1 
jump @TURNOF_1

:TURNOF_2
041E: set_radio_station 1@
08C3: clear 0@ bit 0 
08BD: set 0@ bit 1
jump @TURNOF_1

Last edited by mfisto (17-04-2009 10:17)

Sw[ee]t · 17-04-2009 14:02

Вылетает.

flashTrash · 17-04-2009 18:56

@Sw[ee]t

{$CLEO}
thread "TURNOF"

while true
wait 0
    if and
    Actor.Driving($PLAYER_ACTOR)
    0AB0:  key_pressed 0x58
    then
        03C0: 0@ = actor $PLAYER_ACTOR car
        wait 500
        051E: 1@ = get_current_radio_station 
        041E: set_radio_station 12
        
        while true
        wait 0
            if
            00DB:   actor $PLAYER_ACTOR in_car 0@ 
            then
                if
                0AB0:  key_pressed 0x58
                then
                    041E: set_radio_station 1@
                    wait 500
                    break
                end
            else
                break
            end
        end
    end
end

Sw[ee]t · 18-04-2009 07:03

Та же история.
PS. может из-за того что капюшон мод стоит? rolleyes

mfisto · 18-04-2009 11:20

to Sw[ee]t
ну ты даешь, а самому проверить то на чистой версии слабо что ли...

flashTrash
вариант такой же как и первый - используйте wait только в миссиях или в в начале цикла т.к. он сбивает склейку опкодов, да к тому же он не гарантирует что ты будешь, как в данном примере, держать клавишу меньше полсекунды.

Sw[ee]t · 18-04-2009 12:13

to mfisto
Чистую игру не мог установить по тех. причинам. Щас проверю

-----------------------------------------------------------
Действительно, поставил на чистую игру - заработало.
спс тем кто помог smile

Last edited by Sw[ee]t (18-04-2009 16:16)

XotaBi4b · 18-04-2009 16:14

Driver wrote:

Ясно с этим я разобрался спасибо всем!) Вот ещё вопрос: Какой опкод можно использовать что бы тачка сама ехала когда я сижу за рулём, но ехала не в указанные кординаты а просто каталась?) Я хочу добавить в скрипт автодраивера(указываешь маркер на карте и тача сама туда едет) такую функцию что бы тачка сама каталась)

Помоему ты сам себе противоречишь.
Возможно вот то что ты ищешь:

{$CLEO}
0000:
while true
wait 600
    if
Player.Defined($PLAYER_CHAR)
    then
    
    if  and
0AB0:  key_pressed 90 
0AB0:   key_pressed 88   // Z + X
    then
0AB5: store_actor $PLAYER_ACTOR closest_vehicle_to 2@ closest_ped_to 1@
if
not 2@ == -1//если  тачка существует ( Thank to Sw[ee]t  he remind me for that check )
8119:   not car 2@ wrecked  //если не взорвалась
then

00A7: car 2@ drive_to -1 -1 -1 //посылаем машину на 3 знака :)
00A8: set_car 2@ to_psycho_driver //водитель психопат :)
//00A9: set_car 2@ to_normal_driver 

//072B: put_actor $PLAYER_ACTOR into_car 2@ passengerseat -1  // садим в машину пассажиром
04BA: set_car 2@ speed_to 22.0
00AD: set_car 2@ max_speed_to 30.0
00AE: set_car 2@ traffic_behaviour_to 2 //не соблюдаем ПДД
02AC: set_car 2@ immunities BP 1 FP 1 EP 1 CP 1 MP 1 // имунитет на машину
    end 
    end
    if  and
0AB0:  key_pressed 90
0AB0:   key_pressed 70   // Z + f   = машина останавливается игрок выходит
Actor.Driving($PLAYER_ACTOR)   //если за рулём
    then
03C0: 2@ = actor $PLAYER_ACTOR car
04BA: set_car 2@ speed_to 0.0
00AD: set_car 2@ max_speed_to 0.0
05CD: AS_actor $PLAYER_ACTOR exit_car 2@
    end

end
end

Вариант1: Если хочешь чтобы тачка каталась без водилы, а ты пассажир, то вкл опкод 072B. в игре садишся только в пустые тачки.
Вариант 2: садишся водителем жмёшь кнопки Z+X и тачка сама ездит. Включать опкод 072B не надо.

Last edited by XotaBi4b (18-04-2009 20:36)

SannyBuilder.com Forums

#901 04-04-2009 11:52

Re: Один вопрос

#902 04-04-2009 19:20

Re: Один вопрос

#903 06-04-2009 15:08

Re: Один вопрос

#904 08-04-2009 05:42

Re: Один вопрос

#905 08-04-2009 09:41

Re: Один вопрос

#906 08-04-2009 16:17

Re: Один вопрос

#907 09-04-2009 18:15

Re: Один вопрос

#908 12-04-2009 13:53

Re: Один вопрос

#909 13-04-2009 18:44

Re: Один вопрос

#910 13-04-2009 23:46

Re: Один вопрос

#911 14-04-2009 08:46

Re: Один вопрос

#912 14-04-2009 15:58

Re: Один вопрос

#913 14-04-2009 16:48

Re: Один вопрос

#914 15-04-2009 05:44

Re: Один вопрос

#915 15-04-2009 10:55

Re: Один вопрос

#916 15-04-2009 22:28

Re: Один вопрос

#917 16-04-2009 04:51

Re: Один вопрос

#918 16-04-2009 16:32

Re: Один вопрос

#919 17-04-2009 10:09

Re: Один вопрос

#920 17-04-2009 14:02

Re: Один вопрос

#921 17-04-2009 18:56

Re: Один вопрос

#922 18-04-2009 07:03

Re: Один вопрос

#923 18-04-2009 11:20

Re: Один вопрос

#924 18-04-2009 12:13

Re: Один вопрос

#925 18-04-2009 16:14

Re: Один вопрос

Board footer